// Get controls present in the PDF file. 
// The different controls of the PDF file are displayed in a Looper control
// Each characteristic of the control corresponds to a row in the Looper control

LooperDeleteAll(LOOP_Control)
CurrentPDF is pdfDocument = PDF_NoName1.Value
sPath is string = CurrentPDF.Value
Trace(sPath)
FOR i = 1 _TO_ CurrentPDF.Page.Count
	page is pdfPage = CurrentPDF.Page[i]
	FOR j = 1 _TO_ page.Control.Count
		control is pdfControl = page.Control[j]
		let sName = control.Name
		let sValue = control.Value
		let sType = ControlTypeToReadableFormat(control.Type)
		let sOptions = ListOption(control)
		// Add details in the Looper control
		LOOP_Control.AddLine(i, j, sName, sType, sValue, sOptions)
		IF sValue <> "" THEN
			LOOP_Control[LOOP_Control.Count].EDT_Value.BackgroundColor = TooltipYellow
		END
		IF sOptions = "" THEN
			LOOP_Control[LOOP_Control.Count].EDT_Option.Grayed = True
		ELSE
			LOOP_Control[LOOP_Control.Count].EDT_Option.Grayed =False
		END
	END
END

INTERNAL PROCEDURE ListOption(control is pdfControl): string
	sOptions is string
	FOR i = 1 _TO_ control.Option.Count
		IF sOptions <> "" THEN sOptions += CR
		sOptions += i + ": " + control.Option[i].Caption
	END
	RETURN sOptions
END
INTERNAL PROCEDURE ControlTypeToReadableFormat(nType): string
	SWITCH nType
		CASE typText: RETURN "Edit control"
		CASE typComboWE: RETURN "Editable Combo Box"
		CASE typComboNE: RETURN "Non-editable Combo Box"
		CASE typCheckBox: RETURN "Check Box"
		CASE typRadioButton: RETURN "Radio Button"
		CASE typList: RETURN "List Box"
		OTHER CASE: RETURN "Unknown"
	END
END