• the first parameter uses the type that must be "extended",
• the prototype of the procedure has the <extension> attribute.

• The extension procedures appear in the code completion suggestions of the extended type.
• Extension procedures cannot be used with types such as Boolean, Integer, Real, Numeric, etc. (any type used to handle numeric values).
• Only WLanguage types can be extended.
• Only global procedures can have the <extension> attribute.
• If the extension procedure overrides a WLanguage function, the standard syntax of that function will also be overridden. For example, creating a "Format" extension procedure for the String type will override both the <String>.Format and StringFormat functions.
• You can chain the calls to extension procedures.
• The 'This' keyword behaves in the same way as in classes or fields: it refers to the element currently being called..
  In an extension procedure, the 'This' keyword refers to the first parameter.
  Therefore, you can use 'This' preceded by 'WL' to refer to standard WLanguage functions and avoid calls to an overloaded function.
  Example:

  PROCEDURE Formate(x is string): string <extension>
  Trace(This) // équivalent à Trace(x)
  RETURN WL.This.Formate(ccUpCase) // Appel le Formate standard

• Procedures can be defined for a given field type using the <type champ>. For example, the following procedure can be used for a Button field:
  

  PROCEDURE Bouton(x is Control <type control = typButton>)

  
  It is possible to extend a procedure for a given field type using the following syntax
  
  PROCÉDURE MaProcédureChampExtension(x est un champ <type champ = xxx>)<extension>
  
  Example:
  

  PROCEDURE ExtensionBouton(x is Control <type control = typButton>) <extension>

Replace tabs with spaces

PROCEDURE RemplaceTABParXEspace(s is string, n is int) <extension>: string
RETURN s.Remplace(TAB, RepeatString(" ", n))

sTexte is string = TAB + "XXX"
Trace(sTexte) // <TAB>XXX
Trace(sTexte.RemplaceTABParXEspace(4)) //     XXX

Extension of the Color type

PROCEDURE CouleurLisible(CouleurOrigine is Color) <extension>: Color
nLuminosité is int
rLuminance is real
CouleurRetour is Color

// Calcul de la luminance de la couleur passée en paramètre
rLuminance = 1 - (0.299 * CouleurOrigine..Red + ...
		0.587 * CouleurOrigine..Green + 0.114 * CouleurOrigine..Blue)/255
// En fonction de la luminance, la couleur d'écriture doit avoir une faible ou une forte luminosité
IF rLuminance < 0.5 THEN
	// Faible luminosité
	nLuminosité = 12
ELSE
	// Forte luminosité
	nLuminosité = 88
END
// La couleur renvoyée conserve la tonalité et la saturation
CouleurRetour = HSL(ColorHue(CouleurOrigine), ColorSaturation(CouleurOrigine), nLuminosité)

RETURN CouleurRetour

// Tableau de couleurs
tabCouleursHTML is array of strings
tabCouleursHTML.Ajoute("#F48FB1")
tabCouleursHTML.Ajoute("#C2185B")
tabCouleursHTML.Ajoute("#64B5F6")
tabCouleursHTML.Ajoute("#1565C0")
tabCouleursHTML.Ajoute("#81C784")
tabCouleursHTML.Ajoute("#2E7D32")

MaCouleur is Color
// Récupère une couleur aléatoire
MaCouleur = HTMLToRGB(tabCouleursHTML[Random(1, tabCouleursHTML..Count)] )
// Applique la couleur initiale en couleur de fond
LIB_TestCouleurFond.CouleurFond = MaCouleur
// Applique une couleur lisible en couleur de texte
LIB_TestCouleurFond.Couleur = MaCouleur.CouleurLisible()