// Load PDF document
My_PDF is pdfDocument = pdf_file_path

// Check the signature
// Execute the procedure only if an invalid signature is detected
PDFVerifySignatures(My_PDF, Verification_procedure)

PROCEDURE Verification_procedure(PDF_doc, Signature_index, Error_code)
// Process the error code
Error_text is string
SWITCH Error_code
	CASE pdfInvalidSignature: Error_text = StringBuild("Signature %1 is invalid", Signature_index)
	CASE pdfCertificateExpired: Error_text = StringBuild("The certificate of the %1 signature has expired", Signature_index)
	CASE pdfModifiedAfterSigning: Error_text = "The PDF file was modified after signing"
END
// Identify invalid signature 
IF Signature_index > 0 THEN
	Error_text += CR + CR
	// Signature details
	let Signature_buffer = PDFGetSignature(PDF_doc, Signature_index)
	certif is Certificate = CertificateExtract(Signature_buffer)
	Error_text += StringBuild([
		Signature number %1
		Issuer: %2
		Name: %3
		Valid from: %4
		Valid until: %5
		Signature date: %6
	],
	Signature_index,
	certif.Issuer,
	certif.Name,
	DateToString(certif.StartValidityDate),
	DateToString(certif.EndValidityDate),
	DateToString(PDFGetSignatureDate(PDF_doc, Signature_index)))
END
// If 
IF ErrorOccurred THEN
	Error_text += CR + CR+ ErrorInfo(errSummary)
	// Displays the error
	Info(Error_text)
	// Stop reading signatures
	RETURN False
ELSE
	// Continue reading signatures
	// If an invalid signature is found, the procedure is restarted. 
	RETURN True
END