Manipulating Organizer controls programmatically (prefix syntax)

ONLINE HELP
WINDEV, WEBDEV AND WINDEV MOBILE

Version:

Home | Sign in | English

Help / Developing an application or website / Controls, windows and pages / Controls: Available types / Organizer control

Overview
Manipulating Organizer controls programmatically
Adding an appointment
Filling an Organizer control with the data found in an HFSQL data file
Retrieving a list of appointments
Displaying an Organizer control from a specific date
Deleting an appointment
Modifying the control display options
Using the context menu (AAF)
Possibilities of the context menu
Advanced use of events with procedures
Management of public holidays
Properties specific to Organizer controls

WINDEV

WEBDEV

WINDEV Mobile

Others

See also

Manipulating Organizer controls programmatically (prefix syntax)

Overview

An Organizer control can be:

manipulated programmatically.
linked to a data file.
bound to a variable.

WINDEV and WEBDEV include the OrganizerXXX functions to manipulate Organizer controls.

This help page explains how to programmatically manipulate an Organizer control in a window or page. The example used in the illustration allows you to store appointments in an HFSQL database.

Manipulating Organizer controls programmatically

Adding an appointment

You can add an appointment to an Organizer control using <Organizer>.AddAppointment. This function accepts two syntaxes:

syntax used to specify the appointment characteristics: title, description, etc.
// Adds an appointment to the Organizer control
ORG_MyOrganizer.AddAppointment("Sales meeting", "201003220845", ...
"201003221230", "Sales")
syntax that handles a variable of type Appointment.
// Declares an Appointment variable
MyAppointment is Appointment
// Fills the appointment
MyAppointment.Title = "Sales meeting"
MyAppointment.Content = "Meeting to discuss the weekly objectives."
MyAppointment.StartDate = "201003220845"
MyAppointment.EndDate = "201003221230"
MyAppointment.Category = "Sales"
MyAppointment.ID = 1
// Adds the appointment into the control
ORG_Organizer.AddAppointment(MyAppointment)

The BackgroundColor property of the Appointment variable is used to define a display color for an appointment. If no background color is defined, the Organizer control will automatically use the color associated with the appointment category.

Filling an Organizer control with the data found in an HFSQL data file

The records are stored in an HFSQL data file. The Organizer control can be initially filled by browsing the data file via the FOR EACH syntax and by adding each appointment via <Organizer>.AddAppointment.

// Appointment variable
MyAppointment is Appointment
// Browse through the appointments stored in the database
FOR EACH APT
// Fills the information of the variable
MyAppointment.Title = APT.Title
MyAppointment.Content = APT.Content
MyAppointment.StartDate = APT.StartDate
MyAppointment.EndDate = APT.EndDate
MyAppointment.Category = APT.Category
MyAppointment.ID = APT.APTID

// Adds the appointment to the Organizer control
ORG_MyOrganizer.AddAppointment(MyAppointment)

END

Reminder: You also have the ability to use an Organizer control linked to a data file. For more details, see Organizer control linked to a data file.

Retrieving a list of appointments

OrganizerListAppointment is used to get:

the list of all appointments in the Organizer control:
// Array containing a list of Appointment
arrAppointmentList is array of Appointment
// Lists of appointments
arrAppointmentList = ORG_MyOrganizer.ListAppointment()
the list of appointments included between two dates:
// List of appointments for January 2010
arrAppointmentList is array of Appointment
// Lists of appointments
arrAppointmentList = ORG_MyOrganizer.ListAppointment("20100101", "20100131")
the appointment currently selected or hovered:
// Selected appointment
arrAppointmentList is array of Appointment
arrAppointmentList = ORG_MyOrganizer.ListAppointment(orgAptSelected)

Displaying an Organizer control from a specific date

To display the Organizer control from a specific date, use <Organizer>.Position.

// Positions the organizer on today's date
ORG_Organizer1.Position(Today())
// Positions the organizer on December 20, 2012
ORG_Organizer1.Position("20121220")

Deleting an appointment

<Organizer>.DeleteAppointment is used to delete:

the appointment selected in the control.
a specific appointment.
// Deletes the first appointment
ORG_MyOrganizer.DeleteAppointment(1)

<Organizer>.DeleteAll deletes all the appointments from the Organizer control.

Modifying the control display options

The current display of an Organizer control can be modified by the following functions:

<Organizer>.DisplayPreviousPeriod and <Organizer>.DisplayNextPeriod: These two functions are used to modify the display period (same as using the spin button found at the top of Organizer control).
<Organizer>.ChangeMode: This function changes the control display mode: day, week, month.
<Organizer>.TimeDisplayed: This function is used to define the time period displayed.

Using the context menu (AAF)

Possibilities of the context menu

The context menu of Organizer control is used to:

change the control display mode,
add, modify or delete an appointment.

To save the operations performed, you must use the events of Organizer control.

In the corresponding event, simply retrieve the appointment currently used and perform the corresponding process.

Example: To store an appointment added by the user via the context menu in an APT data file, simply write the following in the "Entry in edit in an appointment" event:

PROCEDURE Edit(aptEdited is Appointment)

// Store the data
APT.Title = aptEdited.Title
APT.StartDate = aptEdited.StartDate
APT.EndDate = aptEdited.EndDate
...
HAdd(APT)

The same type of code can be used for the different events of the Organizer control. Indeed, a procedure has been automatically declared by the Organizer control for each event in the control that handles an appointment.

These procedures take an Appointment variable as parameter. This variable contains the characteristics of the appointment used by the event.

Advanced use of events with procedures

You can also allow the user to define more precisely the characteristics of his appointment during an addition or a modification. To do so, create a window with the information to specify.

In the code, simply open the window in the "Entry in edit in an appointment" event. To lock the direct input via the context menu of the organizer, the event must return False.

This principle can be applied to all the events called by the context menu of the Organizer control.

Example:

PROCEDURE Edit(aptEdited is Appointment)
// Opens the window for entering an appointment 
// with the selected appointment (in Creation or Modification mode)
Open(WIN_InputAPT_HFSQL, aptEdited)
// Returns False to lock the direct input in the Organizer control
RETURN False

Management of public holidays

Public holidays can be set programmatically. Several WLanguage functions (starting with BankHolidayXXX) are available.

To define the bank holidays displayed in the Organizer controls and in the Calendar controls, you must use BankHolidayAdd. This function allows you to define the list of public holidays to be used. This function allows you to customize the public holidays according to the country and local regulations. This function must be used at the beginning of the application because it has a global effect on the application.

The bank holidays will be colored in green in the Organizer control.

Example:

// Delete all public holidays
BankHolidayDeleteAll()
// Initialize the 11 public holidays common to the French regions and territories
BankHolidayAdd("0101") // 1st of January
BankHolidayAdd(bhEasterMonday) // Easter Monday
BankHolidayAdd("0501") // 1st of May
BankHolidayAdd("0508") // 8th of May
BankHolidayAdd(bhAscensionDay) // Ascension day
BankHolidayAdd(bhWhitMonday) // Whit Monday
BankHolidayAdd("0714") // 14th of July
BankHolidayAdd("0815") // 15th of August (Assumption)
BankHolidayAdd("1101") // All Saints' Day
BankHolidayAdd("1111") // 11th of November
BankHolidayAdd("1225") // Christmas

// Add 2 additional public holidays for the regions of Moselle and Alsace
BankHolidayAdd("1226" + CR + bhGoodFriday)

Properties specific to Organizer controls

The following properties can be used to manipulate Organizer controls.


DirectInputAPT	The DirectInputAPT property is used to determine and specify if the user can directly change the title of an appointment in a Scheduler or Organizer control.
GranularityAppointment	The GranularityAppointment gets and changes the precision of the grid used to define appointments in Organizer or Scheduler controls. Property kept for backward compatibility.
GranularityDuration	The GranularityDuration property is used to get and change the size of the grid to resize: appointments in an Organizer control. appointments in a Scheduler control. events in a TimeLine control. tasks in a Gantt Chart column.
GranularityMovement	The GranularityMovement property is used to get and change the size of the grid to move: appointments in an Organizer control. appointments in a Scheduler control. events in a TimeLine control. tasks in a Gantt Chart column.
MaskTitleDate	The MaskTitleDate property is used to identify and change the input mask used for the title of day columns in Organizer or Scheduler controls
ModificationDurationAPT	The ModificationDurationAPT property is used to determine and specify if the user can modify the duration of an appointment in a Scheduler or Organizer control.
MovementAPT	The MovementAPT property allows you to know and specify whether users can move appointments in a Scheduler or Organizer control.
Num1stDayOfTheWeek	The Num1stDayOfTheWeek property gets and sets the 1st day of the week displayed in: a Calendar control. an Organizer control. a Scheduler control. an Edit control in Date format with Calendar.
PeriodSelection	The PeriodSelection property is used to determine and specify if the user can select a time period in an Scheduler or Organizer control.
WorkingHourEnd	The WorkingHourEnd property is used to identify and change the end time of working hours used: by an Organizer control. by a Scheduler control. by a Gantt Chart column (in a Table or TreeView Table control).
WorkingHourStart	The WorkingHourStart property is used to get and change the start time of working hours used: by an Organizer control. by a Scheduler control. by a Gantt Chart column (in a Table or TreeView Table control).

For a complete list of WLanguage properties that can be used with Organizer controls, see Organizer control properties.